# SPDX-FileCopyrightText: Copyright 2025 Open Mobile Platform LLC <community@omp.ru>
# SPDX-License-Identifier: BSD-3-Clause

cmake_minimum_required(VERSION 3.18)
project(sqlite3_libs_aurora LANGUAGES NONE)

if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(x64|x86_64)$")
    set(SQLITE_AURORA_ABI "x86_64")
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(ARM64|aarch64|arm64)$")
    set(SQLITE_AURORA_ABI "aarch64")
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(ARM|armv7hl|armv7l|armv7)$")
    set(SQLITE_AURORA_ABI "armv7hl")
else()
    message(FATAL_ERROR "Unsupported architecture \"${CMAKE_SYSTEM_PROCESSOR}\"")
endif()

set(SQLITE_PREBUILT_LIB
    "${CMAKE_CURRENT_SOURCE_DIR}/prebuilt/${SQLITE_AURORA_ABI}/libsqlite3.so")

if(NOT EXISTS "${SQLITE_PREBUILT_LIB}")
    message(FATAL_ERROR "Prebuilt SQLite library not found: ${SQLITE_PREBUILT_LIB}")
endif()

add_custom_target(sqlite3_bundle ALL
    COMMAND ${CMAKE_COMMAND} -E make_directory "${CMAKE_BINARY_DIR}/bundle/lib"
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
            "${SQLITE_PREBUILT_LIB}"
            "${CMAKE_BINARY_DIR}/bundle/lib/libsqlite3.so"
    BYPRODUCTS "${CMAKE_BINARY_DIR}/bundle/lib/libsqlite3.so"
    COMMENT "Copying prebuilt SQLite for ${SQLITE_AURORA_ABI}"
)
